Cross Segmento - TOTVS Backoffice (Linha Protheus) - Faturamento - Execauto Rotina Automática Cadastro de Clientes - CRMA980

Dúvida
Preciso de um exemplo da rotina automática de cliente mais atualizada.

Ambiente
Cross Segmento - TOTVS Backoffice (Linha Protheus) – Faturamento – A partir da versão 12.1.17

Solução
Segue abaixo modelo de rotina automática, neste exemplo foi incluído novos campos obrigatórios.

{"A1_INCISS" ,"N" ,Nil},;
{"A1_GRPVEN" ,"000001" ,Nil}}

Exemplo 

#Include "Protheus.ch"
#include "TBICONN.CH"
//-------------------------------------------------------------------
/*/{Protheus.doc} MyCRMA980
Função de exemplo para utilização da rotina automática de Clientes.
/*/
//-------------------------------------------------------------------
User Function MyCRMA980()
 
Local aSA1Auto := {}
Local aAI0Auto := {}
Local nOpcAuto := 3//MODEL_OPERATION_INSERT
Local lRet := .T.
 
Private lMsErroAuto := .F.
 
lRet := RpcSetEnv("T1","D MG 01","Admin")

If lRet
 
 //----------------------------------
 // Dados do Cliente
 //----------------------------------
 aAdd(aSA1Auto,{"A1_COD" ,"XBX141" ,Nil})
 aAdd(aSA1Auto,{"A1_LOJA" ,"01" ,Nil})
 aAdd(aSA1Auto,{"A1_NOME" ,"ROTINA AUTOMATICA" ,Nil})
 aAdd(aSA1Auto,{"A1_NREDUZ" ,"ROTAUTO" ,Nil}) 
 aAdd(aSA1Auto,{"A1_TIPO" ,"F" ,Nil})
 aAdd(aSA1Auto,{"A1_END" ,"BRAZ LEME" ,Nil}) 
 aAdd(aSA1Auto,{"A1_BAIRRO" ,"CASA VERDE" ,Nil}) 
 aAdd(aSA1Auto,{"A1_EST" ,"SP" ,Nil})
 aAdd(aSA1Auto,{"A1_MUN" ,"SAO PAULO" ,Nil})
 aAdd(aSA1Auto,{"A1_INCISS" ,"N" ,Nil})
 aAdd(aSA1Auto,{"A1_GRPVEN" ,"000001" ,Nil})
 
 //---------------------------------------------------------
 // Dados do Complemento do Cliente
 //---------------------------------------------------------
 aAdd(aAI0Auto,{"AI0_SALDO" ,30 ,Nil})
 
 //------------------------------------
 // Chamada para cadastrar o cliente.
 //------------------------------------
 MSExecAuto({|a,b,c| CRMA980(a,b,c)}, aSA1Auto, nOpcAuto, aAI0Auto)
 
 If lMsErroAuto 
 lRet := lMsErroAuto
 MostraErro() // Não funciona na execução via JOB
 Else
 Conout("Cliente incluído com sucesso!")
 EndIf
 
EndIf
 
RpcClearEnv()
 
Return lRet

Saiba Mais

DT Novo Fonte de Cadastro de Clientes em MVC

Cross Segmentos - TOTVS Backoffice (Linha Protheus) - SIGAFAT - Rotina Cadastro de Cliente (MATA030) Descontinuada