Cross Segmento - TOTVS Backoffice (Linha Protheus) - SIGAFAT - EXECAUTO FATA300

#Include "Protheus.ch"

User Function MyFATA300()

    Local aCabec        := {}
    Local lRet          := .T.
    Local lTodosSim     := .F.
    Private lMsErroAuto := .F.

    dbSelectArea("AD1")
    dbSetOrder(1)

    ConOut("Teste de Inclusao de Oportunidade")
    ConOut("Inicio: " + Time())
    ConOut("Montando o array do cabecalho")

    If !dbSeek(xFilial("AD1")+"000001"+"02")
    // Monta o array com as informacoes para a gravacao
        aCabec := {{ "AD1_FILIAL"  ,""                    ,NIL },;
                   { "AD1_NROPOR"  ,"000001"              ,NIL },;  //Numero da Oportunidade
                   { "AD1_REVISA"  ,"01"                  ,NIL },;
                   { "AD1_DESCRI"  ,"TESTE DE ROT AUTOM"  ,NIL },;
                   { "AD1_DATA  "  ,DATE()                ,NIL },;
                   { "AD1_HORA  "  ,SUBSTR(TIME(),1,5)    ,NIL },;
                   { "AD1_USER  "  ,"000000"              ,NIL },;
                   { "AD1_VEND  "  ,"000001"              ,NIL },;
                   { "AD1_DTINI "  ,DATE()                ,NIL },;
                   { "AD1_PROSPE"  ,""                    ,NIL },;
                   { "AD1_LOJPRO"  ,""                    ,NIL },;
                   { "AD1_CODCLI"  ,"000001"              ,NIL },;
                   { "AD1_LOJCLI"  ,"01"                  ,NIL },;
                   { "AD1_PROVEN"  ,"000001"              ,NIL },;
                   { "AD1_STAGE "  ,"000001"              ,NIL },;
                   { "AD1_MOEDA "  ,1                     ,NIL },;
                   { "AD1_PRIOR "  ,"1"                   ,NIL }}       
    EndIf    

    lTodosSim := ApMsgNoYes('Confirma a acao [Sim p/Todos]?')

    //ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿//³Gravacao da oportunidade³//ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

    If lTodosSim
        ConOut("Iniciando a gravacao")
        MSExecAuto({|x,y|FATA300(x,y)},3,aCabec)

        If lMsErroAuto
            Conout('Erro ao cadastrar Oportunidade!')
            DisarmTransaction()
            MostraErro()
            lRet := .F.
        Else
            Conout('Oportunidade cadastrada com Sucesso!')
            lRet := .T.
        EndIf

        ConOut("Fim: " + Time())
    EndIf

Return lRet