FAQs - Suporte técnico

Cross Segmento - TOTVS Backoffice Linha Protheus - ADVPL - Funções para impressora não fiscal

Ocorrência
Ao tentar realizar uma impressão customizada no módulo SIGALOJA com a impressora não fiscal habilitada (-A -A={PORT}) não é obtido sucesso.

Ambiente
Cross Segmento - TOTVS Backoffice (Linha Protheus) – ADVPL – A partir da versão 11.8

Causa
Caso tentado efetuar a abertura da impressora, será gerado um erro informado que a mesma já está em uso. Isto ocorre, pois quando existe uma thread ativa com a impressora, o Protheus realiza o travamento do uso por aplicações externas.

Solução
Não realizar a abertura da impressora novamente, apenas utilizar as funções de impressão disponibilizadas.

Exemplo

// BIBLIOTECAS NECESSÁRIAS
#Include "TOTVS.ch"

//------------------------------------------------------
// REALIZA A IMPRESSÃO DE UM CUPOM FISCAL NO SIGALOJA
//------------------------------------------------------
User Function T227IMPNF()
Local nMaxChar := 47 // MÁXIMO DE CARACTERES POR LINHA
Local aMessage := {} // MENSAGEM LONGA

// CENTRALIZADO E EM NEGRITO
INFTexto("<b>" + PadC("TOTVS S/A", nMaxChar) + "</b>")
INFTexto(PadC("CNPJ: 59.754.541/0001-58", nMaxChar))

// MODELO DE AJUSTE POR LINHA E COLUNA
INFTexto(DToC(dDatabase) + Space(1) + Time() + Space(nMaxChar - 30) + "COD: " + StrZero(Randomize(1, 999999), 6))

// LINHA EM BRANCO
INFTexto("<l></l>")

// TÍTULO AUMENTADO
INFTexto("<e>" + PadC("CUPOM DE TROCA", Round(nMaxChar/2, 0)) + "</e>")

// LINHA PONTILHADA
INFTexto(Replicate("-", nMaxChar))

// MENSAGEM COM NO MÁXIMO 47 CARACTERES POR LINHA
AAdd(aMessage, "Para efetuar trocas de mercadoria é necessário")
AAdd(aMessage, "apresentar este cupom ou documento original de")
AAdd(aMessage, "de venda. Produto: PRDT" + StrZero(Randomize(1, 999999), 6) + ".")
AEval(aMessage, {|cMessage| INFTexto(cMessage)})

// PRAZO DE TROCA
INFTexto("Prazo máximo para a troca: " + DToC(dDatabase + 7) + ".")

// LINHA EM BRANCO
INFTexto("<l></l>")

// CÓDIGO DE BARRAS
INFCodeBar("<code128>", "(370)01250(240)405001353400(10)Z064(101)612688")

// LINHA EM BRANCO
INFTexto("<l></l>")

// LINHA PONTILHADA
INFTexto(Replicate("-", nMaxChar))

// RODAPÉ
INFTexto("LOJA: " + StrZero(Randomize(1, 999), 3) + Space(1) +;
"PDV: " + StrZero(Randomize(1, 999), 3) + Space(nMaxChar - 31) +;
"OPERADOR: " + StrZero(Randomize(1, 999), 3))

// LINHA EM BRANCO
INFTexto("<l></l>")

// ACIONA A GUILHOTINA
INFTexto("<gui></gui>")
Return (NIL)


Resultado

IMPRESSORA.gif

Observação
Conforme descrito no próprio boletim oficial (vide Saiba mais), cada impressora terá suas particularidades, isto posto, cabe ao desenvolvedor a validação das funções e qual delas melhor atende ao desenvolvimento da customização.

Saiba mais
SIGALOJA 0130 Customizacao para Impressora Nao Fiscal

Esse artigo foi útil?
Usuários que acharam isso útil: 0 de 0

0 Comentários

Por favor, entre para comentar.
X Fechar

Olá ,

Há pendência referente a um de seus produtos contratados para a empresa ().

Entre em contato com o Centro de Serviços TOTVS para tratativa.

Ligue! 4003-0015 opção 4 e 9 ou registre uma solicitação para CST – Cobrança – Verificação de pendências financeiras . clique aqui.

TOTVS

X Fechar

Olá ,

Seu contato não está cadastrado no Portal do Cliente como um perfil autorizado a solicitar consultoria telefônica.

Por gentileza, acione o administrador do Portal de sua empresa para: (1)configurar o seu acesso ou (2)buscar um perfil autorizado para registro desse atendimento.

Em caso de dúvidas sobre a identificação do contato administrador do Portal, ligue (11) 4003-0015, opção 7 e, em seguida, opção 4 para buscar o suporte com o time de Assessoria ao Portal do Cliente. . clique aqui.

TOTVS

X Fechar

Olá ,

Para o atendimento de "Consultoria Telefônica" você deverá estar de acordo com o Faturamento.

TOTVS

X Fechar

Olá,

Algo inesperado ocorreu, e o usuario nao foi reconhecido ou você nao se encontra logado

Por favor realize um novo login

Em caso de dúvidas, entre em contato com o administrador do Portal de Clientes de sua empresa para verificação do seu usuário, ou Centro de Serviços TOTVS.

Ligue! 4003-0015 opção 4 e 9 ou registre uma solicitação para CST – Cadastros . clique aqui.

TOTVS

Chat _

Preencha os campos abaixo para iniciar o atendimento:

Chat _