Cross Segmento - TOTVS Backoffice Linha Protheus - ADVPL - Consumo de web services com totvs http broker

// BIBLIOTECAS NECESSÁRIAS
#Include "TOTVS.ch"

//------------------------------------------------------
// REALIZA CONSUMO EM SERVIÇOS QUE UTILIZAM BROKER HTTP
//------------------------------------------------------
User Function T225BROKER()
    Local aHeader   := {}        // CABEÇALHO
    Local oRest     := RestDef() // CLIENTE DE REQUISIÇÃO
    Local cResponse := Space(0)  // RESPOSTA
    Local cCookie   := Space(0)  // COOKIE PARA ENVIO

    // DEFINE O RETORNO OBRIGATÓRIO DO SERVIÇO
    AAdd(aHeader, "Content-Type: application/json")

    // REALIZA O PRIMEIRO POST
    If (oRest:Post(aHeader))
        // VERIFICA SE FOI ENVIADO ALGO NA RESPOSTA DA REQUISIÇÃO
        If (Len(oRest:oResponseH:aHeaderFields) > 0)
            // CASO TENHA SIDO ENVIADO, ENCONTRA O CONTEÚDO DE SET-COOKIE
            cCookie := oRest:oResponseH:aHeaderFields[AScan(oRest:oResponseH:aHeaderFields, {|x| Upper(AllTrim(x[1])) == "SET-COOKIE"})][2]

            // EXTRAI APENAS O COOKIE DO CABEÇALHO DE RETORNO
            cCookie := StrTokArr2(cCookie, ";", .F.)[1]

            // ADICIONA O COOKIE NO CABEÇALHO DA NOVA REQUISIÇÃO
            AAdd(aHeader, "Cookie: " + EncodeUTF8(cCookie))
            oRest := RestDef()
 
            // REALIZA O SEGUNDO POST
            If (oRest:Post(aHeader))
                cResponse := oRest:GetResult()
            Else
                cResponse := oRest:GetLastError()
            EndIf
        EndIf
    Else
        cResponse := oRest:GetLastError()
    EndIf
Return (NIL)

//------------------------------------------------------
// GERA UM CLIENTE DE REQUISIÇÃO PRONTO DA EXECUÇÃO
//------------------------------------------------------
Static Function RestDef()
    Local cURI  := "http://minhaempresaqui.protheus.cloudtotvs.com.br:4050/rest" // URL DO SERVIÇO
    Local cPath := "/fornecedor"                                                 // RECURSO SOLICITADO
    Local oRest := FwRest():New(cURI)                                            // CLIENTE DE REQUISIÇÃO

    // DEFINE O RECURSO E O CORPO DA REQUISIÇÃO (BODY)
    oRest:SetPath(cPath)
    oRest:SetPostParams(JsonDef())
Return (oRest)

//------------------------------------------------------
// REALIZA A MONTAGEM DO JSON DO CORPO DA REQUISIÇÃO
//------------------------------------------------------
Static Function JsonDef()
    Local bJson := {|| JsonObject():New()} // OBJETO DE MACROEXECUÇÃO
    Local oJson := Eval(bJson)             // JSON DO CORPO DA REQUISIÇÃO (BODY)

    // VETOR DE CAMPOS
    oJson["fornecedor"] := {}

    // CAMPOS DO VETOR
    AAdd(oJson["fornecedor"], Eval(bJson))
    oJson["fornecedor"][Len(oJson["fornecedor"])]["field"] := "A2_COD"
    oJson["fornecedor"][Len(oJson["fornecedor"])]["value"] := "000001"

    AAdd(oJson["fornecedor"], Eval(bJson))
    oJson["fornecedor"][Len(oJson["fornecedor"])]["field"] := "A2_LOJA"
    oJson["fornecedor"][Len(oJson["fornecedor"])]["value"] := "01"

    /* DEMAIS INFORMAÇÕES DO JSON AQUI */
Return (oJson:ToJson())