Tiempo aproximado de lectura 00:03:00 min
Duda
¿Cuál es la funcionalidad del Punto de Entrada FA074NAT en la rutina de Diferencia de Cambio para Cuentas por Cobrar (FINA074)?
Entorno
Cross Segmentos - TOTVS BackOffice (Línea Protheus) - MI - Financiero (SIGAFIN) - Versión 12
Solución
El Punto de Entrada FA074NAT tiene como objetivo principal permitir al usuario definir y solicitar una 'modalidad' específica durante el proceso de generación de diferencia de cambio. Esta modalidad será utilizada para generar los títulos correspondientes, como las Notas de Crédito (NCC) y Notas de Débito (NDC) resultantes de la rutina FINA074.
Su aplicación habilita una ventana de selección manual que permite asignar la modalidad a los documentos generados por diferencia cambiaria, brindando mayor flexibilidad frente a las parametrizaciones estándar del proceso.
Reglas de devolución y parámetros: El punto de entrada recibe un parámetro automático (PARAMIXB de tipo carácter) que indica el tipo de documento a generar (NCC o NDC). La devolución del punto de entrada debe ser, obligatoriamente, una variable de tipo carácter (cModalidad) con la modalidad que será asignada a los títulos. Importante: Si el Punto de entrada no retorna ninguna modalidad (cadena vacía), el sistema conservará la modalidad definida por defecto en los parámetros de la rutina FINA074.
Ejemplo de uso
#include "totvs.ch"
User Function FA074NAT()
Local cTipoDoc := "" as Character
Local cModalidad := "" as Character
// Se obtiene el tipo de documento (E1_TIPO) enviado por FINA074.
cTipoDoc := PARAMIXB
cModalidad := FA074Mod(cTipoDoc)
// Si no se determino una modalidad, se respeta la naturaleza del estándar.
If Empty(cModalidad)
Return ""
EndIf
Return cModalidad
/*/{Protheus.doc} FA074Mod
Funcion determinada para obtener la modalidad dependiendo el tipo de documento
/*/
Static Function FA074Mod(cTipoDoc)
Local oDlg as Object
Local oGet
Local lConfirmado := .F.
Local cModalidad := CriaVar("E1_NATUREZ")
Default cTipoDoc := ""
DEFINE MSDIALOG oDlg TITLE "Indique Modalidad" FROM 0, 0 TO 200, 300 PIXEL
@ 27, 08 SAY "Modalidad:" SIZE 25, 7 OF oDlg PIXEL
@ 27, 36 MSGET oGet VAR cModalidad F3 "SED" Picture PesqPict("SED", "E1_NATUREZ") VALID ExistCpo("SED", cModalidad) SIZE 50, 08 OF oDlg PIXEL
@ 70, 25 BUTTON "Confirmar" ACTION (lConfirmado := .T., oDlg:End()) SIZE 40, 15 OF oDlg PIXEL
@ 70, 70 BUTTON "Cancelar" ACTION (lConfirmado := .F., oDlg:End()) SIZE 40, 15 OF oDlg PIXEL
ACTIVATE MSDIALOG oDlg CENTERED
If !lConfirmado
cModalidad := ""
EndIf
Return cModalidad
Nota El análisis, debug y ajuste a funciones de usuario, Puntos de Entrada y/o Asientos contables estándar, exceden el alcance del soporte TOTVS al producto estándar.
Conozca más:
PE FA074NAT Modalidad para todos los documentos generados por diferencia cambiaria FINA074
0 Comentarios