Cross Segmentos - TOTVS BackOffice (Línea Protheus) - MI - Financiero (SIGAFIN) - Punto de Entrada FIN846DEL - Validar Anulación/Borrado de Recibo de cobro (FINA846)

Duda
¿Cuál es el punto de entrada para agregar validaciones en la Anulación/Borrado de un Recibo de Cobro?

Ambiente
Cross Segmentos - TOTVS BackOffice (Línea Protheus) - MI - Financiero (SIGAFIN) - A partir da versión 11.80

Solución
Existe el punto de entrada FIN846DEL, el cual fue habilitada para permitir agregar validaciones previo a la anulación/borrado de un recibo de cobro. Con el uso de este punto de entrada se permite controlar las acciones de Anular/Borrar de acuerdo con las reglas definidas en la función de usuario.

Ejemplo:

#Include 'Protheus.ch'

User Function FIN846DEL()
Local cRecibo := Paramixb[1]
Local cSerie := Paramixb[2]
Local cCanc := Paramixb[3]
Local aReturn := {.T.,"","",""} 
Local aAreaFJT := FJT->(GetArea())

DbSelectArea("FJT")
DbSetOrder(1)
If FJT->(MsSeek( xFilial("FJT") + cSerie + cRecibo ))
    WHILE !FJT->(EOF()) .AND. FJT->FJT_SERIE == cSerie .AND. FJT->FJT_RECIBO == cRecibo 
        If FJT->FJT_DTDIGI <> ddatabase
            aReturn[1] := .F. 
        EndIf
    FJT->(DbSkip())
    EndDo
EndIF
RestArea(aAreaFJT)

If aReturn[1] == .F.
    If cCanc <> '1'
        aReturn[2] := "Anulación de recibo"
    Else
        aReturn[2] := "Borrado de recibo"
    EndIf
    aReturn[3] := "No se permite anular/borrar el Recibo"
    aReturn[4] := "Entre en contacto con el administrador del sistema"
EndIf

Return aReturn

Conozca más
Para adquirir más conocimiento, acceda al siguiente enlace de TDN:
DT_Punto_de_Entrada_FIN846DEL_ARG