Duda
¿Cómo generar las reservas de material en la tabla SD4 cuando la Orden de Producción es generada desde ExecAuto de la rutina MATA650?
Ambiente
TOTVS MANUFACTURA - TOTVS Manufactura (Línea Protheus) - MI - Planificación y Control de la Producción (SIGAPCP) - Planificación y Control de la Producción (SIGAPCP) - A partir de la versión 11.80
Solución
Para que el Sistema genere reservas de material en la tabla SD4 al incluir una Orden de Producción desde la rutina automática MATA650, considere habilitar el parámetro MV_EXPLOPU=S e incluir el parámetro {'AUTEXPLODE' ,"S" ,NIL} en el arreglo de campos del ExecAuto.
Bloque de código de ejemplo:
#Include "Protheus.ch"
#include "rwmake.ch"
#include "TbiConn.ch"
User Function xmata650()
Local aMATA650 := {} //Arreglo con los campos
//ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
//³ 3 - Inclusion ³
//³ 4 - Alteracion ³
//³ 5 - Exclusion ³
//ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Local nOpc := 3
Local nOP := GETNUMSC2()
Private lMsErroAuto := .F.
aMata650 := {{'C2_FILIAL' ,"01" ,NIL},;
{'C2_NUM' ,nOP ,NIL},;
{'C2_ITEM' ,"01" ,NIL},;
{'C2_SEQUEN' ,"001" ,NIL},;
{'C2_PRODUTO' ,"01PRODPA ",NIL},;
{'C2_LOCAL' ,"01" ,NIL},;
{'C2_QUANT' ,5 ,NIL},;
{'C2_UM' ,"UN" ,NIL},;
{'C2_DATPRI' ,dDataBase ,NIL},;
{'C2_DATPRF' ,dDataBase ,NIL},;
{'C2_EMISSAO' ,dDataBase ,NIL},;
{'C2_PRIOR' ,"500" ,NIL},;
{'C2_TPOP' ,"F" ,NIL},;
{'AUTEXPLODE' ,"S" ,NIL}}
ConOut("Inicio: " + Time())
//ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
//³ Si es alteración o exclusión, se debe posicionar en el ³
//³ registro de SC2 antes de ejecutar la rutina automática ³
//ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
If nOpc == 4 .Or. nOpc == 5
SC2->(DbSetOrder(1)) // FILIAL + NUM + ITEM + SEQUEN + ITEMGRD
SC2->(DbSeek(xFilial("SC2")+"000001"+"01"+"001"))
EndIf
msExecAuto({|x,Y| Mata650(x,Y)},aMata650,nOpc)
If !lMsErroAuto
ConOut("Proceso Finalizado Satisfactoriamente!")
msginfo("Orden de Producción " + nOP + " incluida satisfactoriamente!")
Else
ConOut("Error!")
MostraErro()
EndIf
ConOut("Fin: " + Time())
Return Nil
Conozca más
Para adquirir más conocimiento acceda al siguiente enlace:
MATA650 - Registro de Orden de Producción
0 Comentarios