Duda
¿Cómo utilizar el ExecAuto para la Inclusion de reglas de descuento. FATA080?
Ambiente
Cross Segmentos - TOTVS Backoffice (Línea Protheus) MI - Facturación (SIGAFAT) - Todas las versiones 12
Todos lo paises.
Solución
Función utilizada para incluir, modificar o eliminar reglas de descuento a través de la rutina automática (ExecAuto).
#INCLUDE "PROTHEUS.CH"
#INCLUDE "TBICONN.CH"
User Function U_MYFATA080()
Local cCodReg := "" // Código de la regla
Local cB1Cod := "0101001" // Código del producto
Local cMsgLog := ""
Local cFilSB1 := ""
Local nOpcX := 3 // Inclusión
Local aCabec := {}
Local aItens := {}
Local aLinha := {}
Local lOk := .T.
Private lMsErroAuto := .F. // Indica si hubo error al ejecutar la rutina automática
Private lMsHelpAuto := .T. // Genera un mensaje de error como archivo .LOG en la system
//****************************************************************
//* Apertura del entorno
//****************************************************************
ConOut("Inicio: " + Time())
ConOut(Repl("-",80))
ConOut(PadC("Proceso de inclusión de reglas de descuento", 80))
//PREPARE ENVIRONMENT EMPRESA "T1" FILIAL "D MG 01" MODULO "FAT" TABLES "ACO","ACP","SA1","SBM"
//****************************************************************
//* Verifica si el producto existe //****************************************************************
SB1->(dbSetOrder(1))
cFilSB1 := xFilial("SB1")
If SB1->(! MsSeek(cFilSB1 + cB1Cod))
cMsgLog += "Registrar el producto: " + cB1Cod + CRLF
lOk := .F.
EndIf
If lOk
//|------------------------------------|
//| Genera código de regla de descuento|
//|------------------------------------|
cCodReg := GetSxeNum("ACO", "ACO_CODREG")
//|---------------------------------|
//| INFORMA ENCABEZADO |
//|---------------------------------|
aCabec := {}
aadd(aCabec, {"ACO_CODREG", cCodReg, Nil})
aadd(aCabec, {"ACO_DESCRI", "INCLUSION REGLA DESCUENTO", Nil})
aadd(aCabec, {"ACO_MOEDA", 1, Nil})
aadd(aCabec, {"ACO_TPHORA", '1', Nil})
aadd(aCabec, {"ACO_HORADE", '00:00', Nil})
aadd(aCabec, {"ACO_HORATE", '23:59', Nil})
aadd(aCabec, {"ACO_DATDE", Date(), Nil})
//|---------------------------------|
//| INFORMA ÍTEMS |
//|---------------------------------|
aLinha := {}
aadd(aLinha,{"ACP_ITEM", '001', Nil})
aadd(aLinha,{"ACP_CODPRO", cB1Cod, Nil})
aadd(aLinha,{"ACP_PERDES", 10, Nil})
aadd(aItens, aLinha)
MSExecAuto({|a, b, c| FATA080(a, b, c)}, aCabec, aItens, nOpcX, .F.)
If !lMsErroAuto
ALERT("INCLUIDO CON EXITO ")
ConOut("¡Incluido con éxito! " + cCodReg)
Else
ALERT("NO SE INCLUYO")
ConOut("¡Error en la inclusión!")
EndIf
Else
ConOut(cMsgLog)
EndIf
ConOut("Fin: " + Time())
RESET ENVIRONMENT
Return
Conozca más.
FATA080 - Reglas de descuento (ExecAuto)
0 Comentarios