Cross Segmentos - TOTVS Backoffice (Línea Protheus) - MI - Stock y Costos (SIGAEST) - ExecAuto Alteración Reservas con PIMS (MATA381) – Central de Atención TOTVS

Tiempo aproximado de lectura: 00:05:00 min

Duda
Ejemplo de ExecAuto para Alteración de Reservas con integración PIMS (MATA381)

Ambiente
Cross Segmentos - TOTVS Backoffice (Línea Protheus) - MI - Stock y Costos (SIGAEST) - Todas las versiones 12

Solución

En el array de cabecera es necesario enviar el número de orden de producción y la clave INDEX con el valor 2, como último ítem del array, para que el sistema cambie la orden de producción correcta.

En el array de items sólo se puede enviar información sobre las reservas que se están modificando. No es necesario cargar en la matriz de reservas que ya están registrados en la tabla SD4 y que no sufrirán ningún cambio. La información de la dirección se puede enviar utilizando la opción AUT_D4_END según el ejemplo.

Cuando la reserva tiene control de lote y el lote se envía para generar la reserva, no es necesario enviar la fecha de vencimiento del lote. El programa MATA381 completa automáticamente la fecha de vencimiento del lote.

Para cambiar una reserva que está registrado en SD4 es necesario utilizar el identificador LINPOS. La clave utilizada en LINPOS debe ser la siguiente concatenación:

D4_COD+D4_TRT+D4_LOTECTL+D4_NUMLOTE+D4_LOCAL+D4_OPORIG+D4_SEQ. Verifique el uso correcto en el ejemplo.
Para eliminar una reserva que está registrado en SD4 es necesario utilizar el identificador LINPOS en conjunto con la clave AUTDELETA. La clave utilizada en LINPOS debe ser la siguiente concatenación:

D4_COD+D4_TRT+D4_LOTECTL+D4_NUMLOTE+D4_LOCAL+D4_OPORIG+D4_SEQ. Verifique el uso correcto en el ejemplo.

Para cambiar la información de la tabla SDC que está vinculada a la reserva, se deben utilizar los identificadores LINPOS y AUTDELETA de la misma forma que se utiliza para los registros de la tabla SD4.

Para cambiar la información de la tabla NLI que está vinculada a la reserva, se deben utilizar los identificadores LINPOS y AUTDELETA de la misma forma que se utiliza para los registros de la tabla SD4.

Para agregar una nueva reserva, simplemente agregue la información sobre está a la matriz de elementos.

Para cambiar reservas, envíe el tercer parámetro de MATA381 con el valor 4.

Ejemplo de alteración con integración con PIMS

User Function Alt381Auto()
    Local nX         := 0
    Local aCab       := {}
    Local aLine      := {}
    Local aItens     := {}
    Local aLineEnder := {}
    Local aEnder     := {}
 
    PRIVATE lMsErroAuto := .F.
 
    //Monta o cabeçalho com o número da OP que será alterada.
    //Necessário utilizar o índice 2 para efetuar a alteração.
    aCab := {{"D4_OP","00130301001",NIL},;
            {"INDEX",2,Nil}}
 
    //Seta o índice da SDC
    SDC->(dbSetOrder(2))
 
    //Busca os empenhos da SD4 para alterar/excluir.
    SD4->(dbSetOrder(2))
    SD4->(dbSeek(xFilial("SD4")+PadR("00130301001",Len(SD4->D4_OP))))
 
    While SD4->(!Eof()) .And. SD4->(D4_FILIAL+D4_OP) == xFilial("SD4")+PadR("00130301001",Len(SD4->D4_OP))
        //Adiciona as informações do empenho, conforme estão na tabela SD4.
        aLine := {}
        For nX := 1 To SD4->(FCount())
            aAdd(aLine,{SD4->(Field(nX)),SD4->(FieldGet(nX)),Nil})
        Next nX
 
 
        //Adiciona as informações da lista de compras (NLI)do empenho, conforme estão na tabela SD4.
        aLineNLI := {}
        For nX := 1 To SD4->(FCount())
            aAdd(aLineNLI,{SD4->(Field(nX)),SD4->(FieldGet(nX)),Nil})
        Next nX
         
        If len(aLineNLI) > 0
            aAdd(aLine,{"AUT_D4_AGR",aLineNLI,NIL})
        Endif
         
         
 
        //Adiciona o identificador LINPOS para identificar que o registro já existe na SD4
        aAdd(aLine,{"LINPOS","D4_COD+D4_TRT+D4_LOTECTL+D4_NUMLOTE+D4_LOCAL+D4_OPORIG+D4_SEQ",;
                            SD4->D4_COD,;
                            SD4->D4_TRT,;
                            SD4->D4_LOTECTL,;
                            SD4->D4_NUMLOTE,;
                            SD4->D4_LOCAL,;
                            SD4->D4_OPORIG,;
                            SD4->D4_SEQ})
         
        //Marca o empenho do produto "MP" como Excluído.
        If AllTrim(SD4->D4_COD) == "MP01"
            aAdd(aLine,{"AUTDELETA","S",Nil})
        ElseIf AllTrim(SD4->D4_COD) == "MP02"
            //Altera a quantidade do empenho do produto "9617-MP1"
            //Busca a informação da quantidade (D4_QTDEORI) no array aLine.
            nX := aScan(aLine,{|x| x[1] == "D4_QTDEORI"})
            If nX > 0
                //Encontrou o valor da quantidade. Faz a alteração do valor.
                aLine[nX,2] := 10
            EndIf
             
            //Altera também o saldo do empenho
            nX := aScan(aLine,{|x| x[1] == "D4_QUANT"})
            If nX > 0
                //Encontrou o valor da quantidade. Faz a alteração do valor.
                aLine[nX,2] := 10
            EndIf
        ElseIf AllTrim(SD4->D4_COD) == "MP03"
            //Altera os endereços utilizado no empenho do produto "9617-MP2"
            //Primeiro carrega os endereços utilizados.
            If SDC->(dbSeek(xFilial("SDC")+SD4->(D4_COD+D4_LOCAL+D4_OP+D4_TRT+D4_LOTECTL+D4_NUMLOTE)))
                //Inicializa o array aEnder
                aEnder     := {}
                 
                //Busca os registros da tabela SDC
                While SDC->(!Eof()) .And. ;
                    xFilial("SDC")+SD4->(D4_COD+D4_LOCAL+D4_OP+D4_TRT+D4_LOTECTL+D4_NUMLOTE) == ;
                    SDC->(DC_FILIAL+DC_PRODUTO+DC_LOCAL+DC_OP+DC_TRT+DC_LOTECTL+DC_NUMLOTE)
                     
                    //Inicializa o array aLineEnder
                    aLineEnder := {}
 
                    //Carrega as informações da tabela SDC no array aLineEnder
                    For nX := 1 To SDC->(FCount())
                        aAdd(aLineEnder,{SDC->(Field(nX)),SDC->(FieldGet(nX)),Nil})
                    Next nX
 
                    //Adiciona o identificador LINPOS para identificar que o registro já existe na tabela SDC
                    aAdd(aLineEnder,{"LINPOS","DC_LOCALIZ+DC_NUMSERI",;
                            SDC->DC_LOCALIZ,;
                            SDC->DC_NUMSERI})
 
                    //Verifica se é o endereço "END". Se for, marca a linha para exclusão.
                    If AllTrim(SDC->DC_LOCALIZ) == "END01"
                        aAdd(aLineEnder,{"AUTDELETA","S",NIL})
                    ElseIf AllTrim(SDC->DC_LOCALIZ) == "END02"
                        //Verifica se é o endereço "END02". Se for, altera a quantidade.
                        //Busca a posição em que a quantidade está no array aLineEnder.
                        nX := aScan(aLineEnder,{|x| x[1] == "DC_QUANT"})
                        If nX > 0
                            //Encontrou a quantidade no array aLineEnder. Faz a alteração da quantidade.
                            aLineEnder[nX,2] := 8
                        EndIf
                    EndIf
                     
                    //Adiciona o endereço no array de endereços.
                    aAdd(aEnder,aLineEnder)
 
                    //Próximo registro da SDC
                    SDC->(dbSkip())
                End
                //Adiciona um novo endereço para ser incluído na tabela SDC.
                //Inicializa o array aLineEnder
                aLineEnder := {}
                 
                //Adiciona as informações do novo endereço.
                aAdd(aLineEnder,{"DC_LOCALIZ","END03",Nil})
                aAdd(aLineEnder,{"DC_QUANT"  ,2      ,Nil})
                 
                //Adiciona o novo endereço no array de endereços.
                aAdd(aEnder,aLineEnder)
 
                //Adiciona as informações de alteração de endereço no array do Empenho.
                aAdd(aLine,{"AUT_D4_END",aEnder,Nil})
            EndIf
        EndIf
 
        //Adiciona as informações do empenho no array de itens.
        aAdd(aItens,aLine)
 
        //Próximo registro da SD4.
        SD4->(dbSkip())
    End
     
    //Adiciona um novo empenho 
    aLine := {}
    aAdd(aLine,{"D4_OP"     ,"00130301001"     ,NIL})
    aAdd(aLine,{"D4_COD"    ,"MP04"            ,NIL})
    aAdd(aLine,{"D4_LOCAL"  ,"01"              ,NIL})
    aAdd(aLine,{"D4_DATA"   ,CtoD("17/09/2018"),NIL})
    aAdd(aLine,{"D4_QTDEORI",5                 ,NIL})
    aAdd(aLine,{"D4_QUANT"  ,5                 ,NIL})
    aAdd(aLine,{"D4_LOTECTL","L1"              ,NIL})
    aAdd(aLine,{"D4_TRT"    ,"004"             ,NIL})
    aAdd(aLine,{"D4_ROTEIRO","01"              ,NIL})
     
    //Adiciona informações referente a integração com o PIMS
    aLineNLI := {}
    aAdd( aLineNLI, { "NLI_CLVAL", "02", Nil } )
    aAdd( aLineNLI, { "NLI_FAZ", "001", NIL } )
    aAdd( aLineNLI, { "NLI_QTCOMP", 20, NIL } )
    aAdd( aLineNLI, { "NLI_PMSQTD", 15, NIL } )
    aAdd( aLineNLI, { "NLI_PGQTD", 25, NIL } )
    aAdd( aLineNLI, { "NLI_POPQTD", 35, NIL } )
    aAdd( aLineNLI, { "NLI_NUMPEN", 01, NIL } )
    aAdd( aLineNLI, { "NLI_QTDPAR", 5000, NIL } )
    aAdd( aLineNLI, { "NLI_CULTRA", "01", NIL } )
    aAdd( aLineNLI, { "NLI_CC", "0010" , NIL } )
    aAdd( aLineNLI, { "NLI_FITSSA", "10", NIL } )
    aAdd( aLineNLI, { "NLI_REQCOD", "admin", NIL } )
    aAdd( aLineNLI, { "NLI_REQNOM", "admin", NIL } )
 
    aAdd(aLine,{"AUT_D4_AGR",aLineNLI,NIL})
 
    aAdd(aItens,aLine)
    //Executa o MATA381, com a operação de Alteração.
    MSExecAuto({|x,y,z| mata381(x,y,z)},aCab,aItens,4)
    If lMsErroAuto
        //Se ocorrer erro.
        MostraErro()
    Else
        Alert("Alterado com sucesso.")
    EndIf
Return

Olá,

Cross Segmentos - TOTVS Backoffice (Línea Protheus) - MI - Stock y Costos (SIGAEST) - ExecAuto Alteración Reservas con PIMS (MATA381)

0 Comentarios

Olá ,

Olá ,

Olá ,

Olá,