Cross Segmento - TOTVS Backoffice (Línea Protheus) - MI - Compras (SIGACOM) – Execauto para generación de factura de flete - MATA101N

Tiempo aproximado para lectura: 1:30 min

Duda
Ejemplo de ExecAuto para generación de factura de flete a través de la rutina MATA101N

Ambiente
Cross Segmento - TOTVS Backoffice (Línea Protheus) - MI - Compras (SIGACOM) – Versión 12

Solución
Sigue ejemplo de MsExecAuto para generación de Factura de Flete mediante rutina MATA101N:

#INCLUDE "RWMAKE.CH" 
#INCLUDE "TBICONN.CH"

//Exemplo de Factura de Entrada - Tipo - Conhecimento de Frete //

User Function xMt101nf()

   Local _aCabec := {} //Array com dados do cabecalho
   Local _aItens := {} //Array com dados do item
   Local aLinha := {} //Array de trabalho 
   Private aRecsSF1 := {} //Array para vinculo de Notas
   Private lMsErroAuto := .f. //Controle de execucao da Rotina 

   //Prepara ambiente de Exemplo //
   PREPARE ENVIRONMENT EMPRESA "01" FILIAL "01" MODULO "COM" TABLES "SF1", "SD1" 

   //Cabecalho
   aadd(_aCabec,{"F1_FILIAL","01"})
   aadd(_aCabec,{"F1_DOC","0000231101006"})
   aadd(_aCabec,{"F1_SERIE","FL"})
   aadd(_aCabec,{"F1_FORNECE","000001"})
   aadd(_aCabec,{"F1_LOJA","01"})
   aadd(_aCabec,{"F1_TIPO","N"})
   aadd(_aCabec,{"F1_FORMUL","N"})
   aadd(_aCabec,{"F1_EMISSAO",dDataBase}) 
   aadd(_aCabec,{"F1_TXMOEDA",1}) 
   aadd(_aCabec,{"F1_ESPECIE","NF"})
   aadd(_aCabec,{"F1_COND","001"}) 
   aadd(_aCabec,{"F1_TIPODOC","14"})

   //Itens
   aadd(_aItens,{"D1_COD","000001 ",nil})
   aadd(_aItens,{"D1_VUNIT",50,nil})
   aadd(_aItens,{"D1_TOTAL",50,nil})
   aadd(_aItens,{"D1_TES","201",nil})
   aadd(_AItens,{"D1_TIPO","C",nil}) 
   aadd(_aItens,{"D1_NFORI","0000231101005",nil}) 
   aadd(_aItens,{"D1_SERIORI","NF ",nil}) 
   aadd(_aItens,{"D1_ITEMORI","0001",nil}) 

   aadd(aLinha,_aItens) 

   //Array de Registro com a Nota de Origem
   aadd(aRecsSF1,5)

   //Executa rotina
   MsExecAuto({|x, y, z| Mata101N(x, y, z)}, _aCabec, aLinha, 3) 

   //Finalizacao
   If lMsErroAuto 
      MostraErro()
   Endif 

   RESET ENVIRONMENT 

Return

Conozca más
Para adquirir más conocimiento, acceda al siguiente enlace:
TDN: ExecAuto - MATA101N - Factura de conocimiento de flete