Duda
¿Cómo se configura la rutina automática para el registro de clientes CRMA980 ?
Ambiente
Cross Segmentos - TOTVS Backoffice (Línea Protheus) MI - Clientes (SIGACOM) - Release 12.1.2210
Solución
Teniendo en cuenta que la rutina CRMA980 ya cuenta con estructura MVC se agregaron nuevos campos y ajuste de otros, por lo que el fuente para la rutina automática, podría quedar de la siguiente manera.
#Include "Protheus.ch"
#include "TBICONN.CH"
//-------------------------------------------------------------------
/*/{Protheus.doc} MyCRMA980
Função de exemplo para utilização da rotina automática de Clientes.
/*/
//-------------------------------------------------------------------
User Function MyCRMA980()
Local aSA1Auto := {}
Local aAI0Auto := {}
Local nOpcAuto := 3//MODEL_OPERATION_INSERT
Local lRet := .T.
Private lMsErroAuto := .F.
lRet := RpcSetEnv("T1","D MG 01","Admin")
If lRet
//----------------------------------
// Dados do Cliente
//----------------------------------
aAdd(aSA1Auto,{"A1_COD" ,"000001" ,Nil})
aAdd(aSA1Auto,{"A1_LOJA" ,"01" ,Nil})
aAdd(aSA1Auto,{"A1_NOME" ,"Cliente prueba" ,Nil})
aAdd(aSA1Auto,{"A1_NREDUZ" ,"ROTAUTO" ,Nil})
aAdd(aSA1Auto,{"A1_TIPO" ,"F" ,Nil})
aAdd(aSA1Auto,{"A1_END" ,"BRAZ LEME" ,Nil})
aAdd(aSA1Auto,{"A1_BAIRRO" ,"CASA VERDE" ,Nil})
aAdd(aSA1Auto,{"A1_EST" ,"SP" ,Nil})
aAdd(aSA1Auto,{"A1_MUN" ,"SAO PAULO" ,Nil})
aAdd(aSA1Auto,{"A1_INCISS" ,"N" ,Nil})
aAdd(aSA1Auto,{"A1_GRPVEN" ,"000001" ,Nil})
//---------------------------------------------------------
// Dados do Complemento do Cliente
//---------------------------------------------------------
aAdd(aAI0Auto,{"AI0_SALDO" ,30 ,Nil})
//------------------------------------
// Chamada para cadastrar o cliente.
//------------------------------------
MSExecAuto({|a,b,c| CRMA980(a,b,c)}, aSA1Auto, nOpcAuto, aAI0Auto)
If lMsErroAuto
lRet := lMsErroAuto
MostraErro() // Não funciona na execução via JOB
Else
Conout("Cliente incluído com sucesso!")
EndIf
EndIf
RpcClearEnv()
Return lRet
Conozca más.
0 Comentarios